Wtyczka Dialer

Ten dokument zgodny jest z NSIS 2.46

Wprowadzenie

Wtyczka dialer dla NSIS udostępnia pięć funkcji związanych z połączeniem z Internetem.

Aby pobrać pliki z Internetu, użyj wtyczki NSISdl.

Sposób użycia

Przykład:

ClearErrors                          ; Czyści flagę błędu
Dialer::NazwaFunkcji           ; Wywołuje funkcje Dialera
IfErrors "" +3                       ; Sprawdza błędy
  MessageBox MB_OK "Funkcja niedostępna"
  Quit
Pop $R0                               ; Pobiera zwracaną wartość ze stosu
MessageBox MB_OK $R0       ; Wyświetla zwracaną wartość

Przykładowa funkcja


 ; ConnectInternet (używa wtyczki Dialer)
 ; Napisał Joost Verburg
 ;
 ; Funkcja ta próbuje utworzyć połączenie z Internetem, jeśli nie jest dostępne żadne połączenie.
 ; Jeśli nie jesteś pewien czy system, na którym uruchomiono instalatora ma aktywne połączenie
 ; z Internetem, wywołaj tę funkcję przed pobieraniem plików przez wtyczkę NSISdl.
 ;
 ; Funkcja wymaga Internet Explorera 3, lecz pyta o ręczne połączenie, jeśli nie jest on zainstalowany.

 Function ConnectInternet

   Push $R0

     ClearErrors
     Dialer::AttemptConnect
     IfErrors noie3

     Pop $R0
     StrCmp $R0 "online" connected
       MessageBox MB_OK|MB_ICONSTOP "Błąd połączenia z Internetem."
       Quit ; Usuń, aby błędy nie były fatalne

     noie3:

     ; IE3 nie zainstalowany
     MessageBox MB_OK|MB_ICONINFORMATION "Proszę, połącz się teraz z Internetem."

     connected:

   Pop $R0

 FunctionEnd

« Powrót do góry

Funkcje

Jeśli dana funkcja nie jest dostepna w systemie, ustawiona zostanie flaga błędu.

AttemptConnect

Próbuje podłączyć system do Internetu, jeśli jeszcze nie jest.

online - już połączony / połączenie udane
offline - połączenie nieudane

Wymagany jest Internet Explorer 3 lub nowszy

AutodialOnline

Powoduje, że modem automatycznie łączy się z domyślnym połączeniem Internetowym, jeśli system nie jest jeszcze podłączony. Jeśli w systemie brak skonfigurowanej opcji automatycznego łączenia z Internetem, użytkownik zostanie zapytany o zgodę na takie połączenie.

Zwracane wartości:

online - już połączony / połączenie udane
offline - połączenie nieudane

Wymagany jest Internet Explorer 4 lub nowszy

AutodialUnattended

Powoduje, że modem automatycznie łączy się z domyślnym połączeniem Internetowym, jeśli system nie jest jeszcze podłączony. Użytkownik nie będzie pytany o zgodę na połączenie.

Zwracane wartości:

online - już połączony / połączenie udane
offline - połączenie nieudane

Wymagany jest Internet Explorer 4 lub nowszy

AutodialHangup

Rozłącza automatyczne połączenie dial-up.

Zwracane wartości:

success - rozłączanie udane
failure - rozłączanie nieudane

Wymagany jest Internet Explorer 4 lub nowszy

GetConnectedState

Sprawdza, czy system jest podłączony do Internetu.

Zwracane wartości:

online - system jest online
offline - system jest offline

Wymagany jest Internet Explorer 4 lub nowszy

Napisał: Amir Szekely aka KiCHiK
Pomoc napisał: Joost Verburg

« Powrót do góry